mapWidth是你的map的宽度
containerWidth是可显示区域的大小
 
private function hoverScroll(e:Event):void
		{
			TweenLite.killTweensOf(map);
			var amountToXScroll:Number = (mapWidth / containerWidth) - 1;
			var mouseXpos:int = mouseX;
			var target:Number = (containerWidth / 2) - ((mouseXpos - (containerWidth / 2)) * amountToXScroll);
			var nuX:Number = target - (map.x + (mapWidth / 2));
			map.x += Math.ceil(nuX / 10);
			//scroll on the y
			var amountToYScroll:Number = (mapHeight / containerHeight) - 1;
			var mouseYpos:int = mouseY;
			var targetY:Number = (containerHeight / 2) - ((mouseYpos - (containerHeight / 2)) * amountToYScroll);
			var nuY:Number = targetY - (map.y + (mapHeight / 2));
			map.y += Math.ceil(nuY / 10);
		}

<!--p header("Content-Type:text/html;charset=utf-8"); define( "DATABASE_SERVER", "localhost"); define( "DATABASE_USERNAME", "root"); define( "DATABASE_PASSWORD", "123456"); define( "DATABASE_NAME", "amfphp"); class PictureWallServer { 	var $output_dir = "temp"; 	 	var $server_url = "http://127.0.0.1/amfphp/services/com/ZhangHaoyun/PictureWall/"; 	 	var $_db; 	public function __construct() 	{ 		try      	 {               $thi-->_db = mysql_connect(DATABASE_SERVER, DATABASE_USERNAME, DATABASE_PASSWORD);
			  mysql_query("set names UTF8");
              mysql_select_db(DATABASE_NAME, $this-&gt;_db);
          }
          catch (Exception $exc)
          {
              return 'ERROR #1: Could not connect to the database';
          }
	}
 
	/**
	 * Save image from the given bytearray
	 * and return the path of the saved image
	 */
 
	function save($ba, $title)
	{
		if(!file_exists($this-&gt;output_dir) || !is_writeable($this-&gt;output_dir))
			trigger_error ("please create a 'temp' directory first with write access", E_USER_ERROR);
 
		$data = $ba-&gt;data;
		$title = "/".$title.".jpg";
 
		file_put_contents($this-&gt;output_dir .$title, $data);
 
		$picurl = $this-&gt;server_url .$this-&gt;output_dir .$title;
 
		$ip=$_SERVER["REMOTE_ADDR"];
 
		$sql="INSERT INTO picwall ( picurl,ip,time) VALUES ('$picurl', '$ip', now());";
 
		$rs=mysql_query($sql, $this-&gt;_db);
		if($rs)
		{
			return "sucess\n".$picurl."\n".$ip;
		}
		else
		{
			return "failed";
		}
	}
 
	/**
	 *Load image url from MySql
	 */
	function load()
	{
		$sql = "SELECT * FROM picwall";
		$rs = mysql_query($sql, $this-&gt;_db);
		return $rs;
	}
 
}
 
?&gt;

package com.zhanghaoyun.picturewall.view
{
	import com.adobe.images.JPGEncoder;
	import com.adobe.images.PNGEncoder;
	import com.zhanghaoyun.picturewall.events.PicWallEvent;
	import flash.display.Bitmap;
	import flash.display.BitmapData;
	import flash.display.MovieClip;
	import flash.events.Event;
	import flash.events.MouseEvent;
	import flash.media.Camera;
	import flash.media.Video;
	import flash.net.NetConnection;
	import flash.net.Responder;
	import flash.ui.Mouse;
	import flash.utils.ByteArray;
	import flash.events.EventDispatcher;
	/**
	 * ...
	 * @author ZhangHaoyun
	 * @web http://www.zhanghaoyun.com
	 */
 
	public class GetImage extends MovieClip
	{
		private var video:Video;
		private var camera:Camera;
		private var w:int;
		private var h:int;
 
		private var bmpd:BitmapData;
		private var bmp:Bitmap;
 
		private var gateway:String = "http://127.0.0.1/amfphp/gateway.php";
 
		private var connection:NetConnection = new NetConnection();
		private var responderSet:Responder;
 
		private var _title:int;
 
		public function GetImage()
		{
			w = vs.width;
			h = vs.height;
			//tip.visible = false;
 
			video = new Video(w, h);
 
			camera = Camera.getCamera();
 
			if (camera == null)
			{
				trace("找不到摄像头");
				tip.visible = true;
				tip.text = "找不到摄像头";
			}
			else
			{
				trace("找到摄像头:" + camera.name);
				camera.setMode(w ,h ,50 ,true);
				video.attachCamera(camera);
				vs.addChild(video);
 
				tip.text = "点击拍摄获取照片";
				btn_pai.addEventListener(MouseEvent.CLICK, paishe);
 
				connection.connect(gateway);
				responderSet = new Responder(onResultSet, onFault);
			}
 
			btnReturn.addEventListener(MouseEvent.CLICK, returnMain);
		}
 
		private function returnMain(e:MouseEvent):void
		{
			var pe:PicWallEvent = new PicWallEvent(PicWallEvent.RETURN);
			dispatchEvent(pe);
			clear();
		}
 
		private function onResultSet(result:Object):void
		{
			trace("sendOk");
			var pe:PicWallEvent = new PicWallEvent(PicWallEvent.PIC_SEND_OK);
			dispatchEvent(pe);
			tip.text = "";
		}
 
		private function onFault(fault:Object):void
		{
			trace("Fault");
			for(var i in fault)
			{
				trace(i + "=>" + fault[i]);
			}
			tip.text = "send fail";
		}
 
		private function paishe(e:MouseEvent):void
		{
			tip.text = "点击确定上传或者从拍";
			getImage();
			btn_pai.removeEventListener(MouseEvent.CLICK, paishe)
			btn_chongPai.addEventListener(MouseEvent.CLICK, chongPai);
			btn_upload.addEventListener(MouseEvent.CLICK, upload);
		}
 
		private function chongPai(e:MouseEvent):void
		{
			tip.text = "点击拍摄获取照片";
			image.removeChildAt(0);
			btn_pai.addEventListener(MouseEvent.CLICK, paishe)
			btn_chongPai.removeEventListener(MouseEvent.CLICK, chongPai);
		}
 
		private function getImage():void
		{
			bmpd = new BitmapData(w, h, true, 0);
			bmpd.draw(video);
			bmp = new Bitmap(bmpd);
			image.addChild(bmp);
		}
 
		private function upload(e:MouseEvent):void
		{
			var jpgEncoder:JPGEncoder = new JPGEncoder();
			var bytes:ByteArray = jpgEncoder.encode(bmpd);
			clear();
			tip.text = "sending..."
			connection.call("com.ZhangHaoyun.PictureWall.PictureWallServer.save", responderSet, bytes, _title);
		}
 
		public function set title(value:int):void
		{
			_title = value;
		}
 
		private function clear():void
		{
			camera = Camera.getCamera(null);
			camera = null;
			video.attachCamera(null);
		}
 
	}
 
}